Make your own free website on Tripod.com

Home
Home

--- Soumis par Dev Ashish---

Le répertoire du système, de Windows, des fichiers temporaires.

(Q) Comment retrouver

    -le répertoire du système?
    -le répertoire temporaire?
    -le répertoire d'installation de Windows?

(A) Copier-coller le code suivant dans un nouveau module, puis, utiliser fReturnSysDir function pour retourner le répertoire du système (eg. C:\win95\System); fReturnWinDir, pour le répertoire d'installation du sysème d'exploitation (eg. C:\Winnt);   fReturnTempDir, pour le répertoire temporaire (eg. C:\Temp\)

'******************** Code Start **************************
Private Const MAX_PATH As Integer = 255
Private Declare Function apiGetSystemDirectory& Lib "kernel32" _
        Alias "GetSystemDirectoryA" _
        (ByVal lpBuffer As String, ByVal nSize As Long)

Private Declare Function apiGetWindowsDirectory& Lib "kernel32" _
        Alias "GetWindowsDirectoryA" _
        (ByVal lpBuffer As String, ByVal nSize As Long)

Private Declare Function apiGetTempDir Lib "kernel32" _
        Alias "GetTempPathA" (ByVal nBufferLength As Long, _
        ByVal lpBuffer As String) As Long
Function fReturnTempDir()
'Retourne le répertoire temporaire
Dim strTempDir As String
Dim lngx As Long
    strTempDir = String$(MAX_PATH, 0)
    lngx = apiGetTempDir(MAX_PATH, strTempDir)
    If lngx <> 0 Then
        fReturnTempDir = Left$(strTempDir, lngx)
    Else
        fReturnTempDir = ""
    End If
End Function
Function fReturnSysDir()
'Retourne le répertoire du système (C:\WinNT\System32)
Dim strSysDirName As String
Dim lngx As Long
    strSysDirName = String$(MAX_PATH, 0)
    lngx = apiGetSystemDirectory(strSysDirName, MAX_PATH)
    If lngx <> 0 Then
        fReturnSysDir = Left$(strSysDirName, lngx)
    Else
        fReturnSysDir = ""
    End If
End Function
Function fReturnWinDir()
'Retourne le répertoire d'installation du système  (C:\Win95)
Dim strWinDirName As String
Dim lngx As Long
    strWinDirName = String$(MAX_PATH, 0)
    lngx = apiGetWindowsDirectory(strWinDirName, MAX_PATH)
    If lngx <> 0 Then
        fReturnWinDir = Left$(strWinDirName, lngx)
    Else
        fReturnWinDir = ""
    End If
End Function
'******************** Code End**************************